 include.eve (No.4329 への返信) - 白河 愁 |
#==========================================================
#
# Ｖガンダム分離先決定インクルード
#
# パーツ分離時に、トップファイターになるか
# ボトムファイターになるかをアイテム制御でランダムに設定します。
# ユニットとしてはトップファイターの方が優秀でしょうが、
# ボトムファイターの出番が無いのも寂しいですからね。(^^;
# なお分離時にオーバーハングなどの追加武装は吹っ飛んだとみなし、
# 再合体時には無印に戻るようにしてあります。
#
# なお、シナリオ中で生成されたユニットは対象外となっております。
# 個別に「トップファイター分離」か「ボトムファイター分離」を
# 装備して対応して下さい。
#
#==========================================================
#----------------------------------------------------------
# 戦闘開始時に、分離先アイテムを付けて回る
#----------------------------------------------------------
*スタート:
ForEach 全 全て
If 対象パイロット <> "" Then
Switch Unit(対象パイロット)
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体) ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体) Ｖ２ガンダム Ｖ２ガンダム(再合体)
Call Ｖガンダム分離先アイテム装備 対象パイロット
EndSw
EndIf
Next
Exit
#----------------------------------------------------------
# 再合体時に、分離先アイテムを付け直す
#----------------------------------------------------------
*使用 トップファイター(Ｖ) Ｖモード:
*使用 ボトムファイター(Ｖ) Ｖモード:
*使用 トップファイター(ヘキサ) Ｖモード:
*使用 ボトムファイター(ヘキサ) Ｖモード:
*使用 トップファイター(Ｖ２) Ｖモード:
*使用 ボトムファイター(Ｖ２) Ｖモード:
If Unit(対象パイロット) = トップファイター(Ｖ) Then
Call 戦艦よりリム射出 ボトムリム ヴィクトリーガンダム(再合体) 対象パイロット
ElseIf Unit(対象パイロット) = ボトムファイター(Ｖ) Then
Call 戦艦よりリム射出 トップリム ヴィクトリーガンダム(再合体) 対象パイロット
ElseIf Unit(対象パイロット) = トップファイター(ヘキサ) Then
Call 戦艦よりリム射出 ボトムリム ヴィクトリーガンダムヘキサ(再合体) 対象パイロット
ElseIf Unit(対象パイロット) = ボトムファイター(ヘキサ) Then
Call 戦艦よりリム射出 トップリム ヴィクトリーガンダムヘキサ(再合体) 対象パイロット
ElseIf Unit(対象パイロット) = トップファイター(Ｖ２) Then
Call 戦艦よりリム射出 ボトムリム(Ｖ２) Ｖ２ガンダム(再合体) 対象パイロット
ElseIf Unit(対象パイロット) = ボトムファイター(Ｖ２) Then
Call 戦艦よりリム射出 トップリム(Ｖ２) Ｖ２ガンダム(再合体) 対象パイロット
EndIf
Call Ｖガンダム分離先アイテム装備 対象パイロット
Exit
#----------------------------------------------------------
# アイテム装備処理の本体
#----------------------------------------------------------
Ｖガンダム分離先アイテム装備:
If (Random(2) = 1) Then
Call トップファイター分離装備 Args(1)
Else
Call ボトムファイター分離装備 Args(1)
EndIf
Return
トップファイター分離装備:
If (IsEquiped(Args(1),トップファイター分離) = 0) Then
If (IsEquiped(Args(1),ボトムファイター分離) = 1) Then
RemoveItem Args(1) ボトムファイター分離
EndIf
Item トップファイター分離
Equip Args(1) トップファイター分離
EndIf
Return
ボトムファイター分離装備:
If (IsEquiped(Args(1),ボトムファイター分離) = 0) Then
If (IsEquiped(Args(1),トップファイター分離) = 1) Then
RemoveItem Args(1) トップファイター分離
EndIf
Item ボトムファイター分離
Equip Args(1) ボトムファイター分離
EndIf
Return
#==========================================================
#
# Ｖガンダムパーツ換装インクルード
#
# やはりＶガンダムは味方からパーツをもらって再合体、
# というのも魅力なので作っちゃいました。
# Ｖガンダム、トップファイター、ボトムファイターで
# 再合体できるの組み合わせがあれば、合体できます。
# 合体後にコアファイターしか残らない場合は、撤退扱いとなります。
# また、合体のための分離時に、オーバーハングパックなどの
# 追加武装は吹っ飛んだ扱いにしています。
#
#==========================================================
ユニットコマンド ボトムリム換装 トップファイター(Ｖ):
ユニットコマンド トップリム換装 ボトムファイター(Ｖ):
ユニットコマンド ボトムリム換装 トップファイター(ヘキサ):
ユニットコマンド トップリム換装 ボトムファイター(ヘキサ):
ユニットコマンド ボトムリム換装 トップファイター(Ｖ２):
ユニットコマンド トップリム換装 ボトムファイター(Ｖ２):
Local イベントパイロット
Local 換装するリム
Local 配列元ネタ_パイロット名称
Local 配列元ネタ_表示用データ
Local 配列データ_パイロット名称
Local 配列データ_表示用データ
Local 選択されたデータ
イベントパイロット = 対象パイロット
If Unit(イベントパイロット) = トップファイター(Ｖ) Then
換装するリム = ボトムリム
ElseIf Unit(イベントパイロット) = トップファイター(ヘキサ) Then
換装するリム = ボトムリム
ElseIf Unit(イベントパイロット) = トップファイター(Ｖ２) Then
換装するリム = ボトムリム
Else
換装するリム = トップリム
EndIf
配列元ネタ_パイロット名称 = ""
配列元ネタ_表示用データ = ""
ForEach 味方 出撃
If ((対象パイロット <> "") And (Call(ユニット間距離,イベントパイロット,対象パイロット) <= 3)) Then
If ((Unit(イベントパイロット) = トップファイター(Ｖ)) Or (Unit(イベントパイロット) = トップファイター(ヘキサ))) Then
Switch Unit(対象パイロット)
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体) ボトムファイター(Ｖ) ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体) ボトムファイター(ヘキサ)
配列元ネタ_パイロット名称 = 配列元ネタ_パイロット名称 & 対象パイロット & ","
配列元ネタ_表示用データ = 配列元ネタ_表示用データ & Info(ユニット,UnitID(対象パイロット),愛称) & "（" & Info(パイロット,対象パイロット,愛称) & "）,"
EndSw
ElseIf ((Unit(イベントパイロット) = ボトムファイター(Ｖ)) Or (Unit(イベントパイロット) = ボトムファイター(ヘキサ))) Then
Switch Unit(対象パイロット)
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体) トップファイター(Ｖ) ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体) トップファイター(ヘキサ)
配列元ネタ_パイロット名称 = 配列元ネタ_パイロット名称 & 対象パイロット & ","
配列元ネタ_表示用データ = 配列元ネタ_表示用データ & Info(ユニット,UnitID(対象パイロット),愛称) & "（" & Info(パイロット,対象パイロット,愛称) & "）,"
EndSw
ElseIf (Unit(イベントパイロット) = トップファイター(Ｖ２)) Then
Switch Unit(対象パイロット)
Case Ｖ２ガンダム Ｖ２ガンダム(再合体) ボトムファイター(Ｖ２)
配列元ネタ_パイロット名称 = 配列元ネタ_パイロット名称 & 対象パイロット & ","
配列元ネタ_表示用データ = 配列元ネタ_表示用データ & Info(ユニット,UnitID(対象パイロット),愛称) & "（" & Info(パイロット,対象パイロット,愛称) & "）,"
EndSw
ElseIf (Unit(イベントパイロット) = ボトムファイター(Ｖ２)) Then
Switch Unit(対象パイロット)
Case Ｖ２ガンダム Ｖ２ガンダム(再合体) トップファイター(Ｖ２)
配列元ネタ_パイロット名称 = 配列元ネタ_パイロット名称 & 対象パイロット & ","
配列元ネタ_表示用データ = 配列元ネタ_表示用データ & Info(ユニット,UnitID(対象パイロット),愛称) & "（" & Info(パイロット,対象パイロット,愛称) & "）,"
EndSw
EndIf
EndIf
Next
If ( Len( 配列元ネタ_パイロット名称 ) <> 0 ) Then
配列元ネタ_パイロット名称 = Left( 配列元ネタ_パイロット名称, Len( 配列元ネタ_パイロット名称 ) - 1 )
Array 配列データ_パイロット名称 配列元ネタ_パイロット名称 ","
Else
Talk システム
$(換装するリム)を射出するユニットがいません！
End
Exit
EndIf
If ( Len( 配列元ネタ_表示用データ ) <> 0 ) Then
配列元ネタ_表示用データ = Left( 配列元ネタ_表示用データ, Len( 配列元ネタ_表示用データ ) - 1 )
Array 配列データ_表示用データ 配列元ネタ_表示用データ ","
EndIf
Ask 配列データ_表示用データ "$(換装するリム)を射出するユニットを選択して下さい" キャンセル可
If 選択 = "" Then
Exit
EndIf
選択されたデータ = 選択
If Unit(イベントパイロット) = トップファイター(Ｖ) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体)
Call ガンダムよりリム射出 トップファイター(Ｖ) 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダム(再合体) イベントパイロット
Case ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体)
Call ガンダムよりリム射出 トップファイター(ヘキサ) 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダム(再合体) イベントパイロット
Case ボトムファイター(Ｖ) ボトムファイター(ヘキサ)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダム(再合体) イベントパイロット
EndSw
ElseIf Unit(イベントパイロット) = ボトムファイター(Ｖ) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体)
Call ガンダムよりリム射出 ボトムファイター(Ｖ) 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダム(再合体) イベントパイロット
Case ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体)
Call ガンダムよりリム射出 ボトムファイター(ヘキサ) 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダム(再合体) イベントパイロット
Case トップファイター(Ｖ) トップファイター(ヘキサ)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダム(再合体) イベントパイロット
EndSw
ElseIf Unit(イベントパイロット) = トップファイター(ヘキサ) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体)
Call ガンダムよりリム射出 トップファイター(Ｖ) 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
Case ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体)
Call ガンダムよりリム射出 トップファイター(ヘキサ) 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
Case ボトムファイター(Ｖ) ボトムファイター(ヘキサ)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] ボトムリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
EndSw
ElseIf Unit(イベントパイロット) = ボトムファイター(ヘキサ) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case ヴィクトリーガンダム ヴィクトリーガンダム(再合体)
Call ガンダムよりリム射出 ボトムファイター(Ｖ) 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
Case ヴィクトリーガンダムヘキサ ヴィクトリーガンダムヘキサ(再合体)
Call ガンダムよりリム射出 ボトムファイター(ヘキサ) 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
Case トップファイター(Ｖ) トップファイター(ヘキサ)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] トップリム ヴィクトリーガンダムヘキサ(再合体) イベントパイロット
EndSw
ElseIf Unit(イベントパイロット) = トップファイター(Ｖ２) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case Ｖ２ガンダム Ｖ２ガンダム(再合体)
Call ガンダムよりリム射出 トップファイター(Ｖ２) 配列データ_パイロット名称[選択されたデータ] ボトムリム(Ｖ２) Ｖ２ガンダム(再合体) イベントパイロット
Case ボトムファイター(Ｖ２)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] ボトムリム(Ｖ２) Ｖ２ガンダム(再合体) イベントパイロット
EndSw
ElseIf Unit(イベントパイロット) = ボトムファイター(Ｖ２) Then
Switch Unit(配列データ_パイロット名称[選択されたデータ])
Case Ｖ２ガンダム Ｖ２ガンダム(再合体)
Call ガンダムよりリム射出 ボトムファイター(Ｖ２) 配列データ_パイロット名称[選択されたデータ] トップリム(Ｖ２) Ｖ２ガンダム(再合体) イベントパイロット
Case トップファイター(Ｖ２)
Call ファイターよりリム射出 配列データ_パイロット名称[選択されたデータ] トップリム(Ｖ２) Ｖ２ガンダム(再合体) イベントパイロット
EndSw
EndIf
IncreaseMorale イベントパイロット -10
Finish イベントパイロット
Exit
#----------------------------------------------------------
# Args(1)：射出元ユニット名
# Args(2)：射出元パイロット名
# Args(3)：射出パーツ名
# Args(4)：受け取り先ユニット名
# Args(5)：受け取り先パイロット名
#----------------------------------------------------------
ガンダムよりリム射出:
Transform Args(2) Args(1)
Call 戦闘アニメ_飛来アップ Info(ユニットデータ,Args(3),グラフィック)
Redraw
Refresh
Transform Args(5) Args(4)
PlaySound Transform.wav
Call Ｖガンダム分離先アイテム装備 Args(5)
RecoverHP Args(2) 100
RecoverHP Args(5) 100
Return
#----------------------------------------------------------
# Args(1)：射出元パイロット名
# Args(2)：射出パーツ名
# Args(3)：受け取り先ユニット名
# Args(4)：受け取り先パイロット名
#----------------------------------------------------------
ファイターよりリム射出:
Escape Args(1)
Call 戦闘アニメ_飛来アップ Info(ユニットデータ,Args(2),グラフィック)
Redraw
Refresh
Transform Args(4) Args(3)
PlaySound Transform.wav
Call Ｖガンダム分離先アイテム装備 Args(4)
RecoverHP Args(4) 100
Return
#----------------------------------------------------------
# Args(1)：射出パーツ名
# Args(2)：受け取り先ユニット名
# Args(3)：受け取り先パイロット名
#----------------------------------------------------------
戦艦よりリム射出:
Call 戦闘アニメ_飛来アップ Info(ユニットデータ,Args(1),グラフィック)
Redraw
Refresh
PlaySound Transform.wav
Call Ｖガンダム分離先アイテム装備 Args(3)
RecoverHP Args(3) 100
Return
ユニット間距離:
Local xdiff ydiff
xdiff = Abs(X(Args(1)) - X(Args(2)))
ydiff = Abs(Y(Args(1)) - Y(Args(2)))
Return (xdiff + ydiff)
#----------------------------------------------------------
# どういうわけかパーツ分離時にHPが100%にならないので、
# HPを100にするように追加。
#----------------------------------------------------------
*分離 トップファイター(Ｖ) ヴィクトリーガンダム:
*分離 ボトムファイター(Ｖ) ヴィクトリーガンダム:
*分離 トップファイター(Ｖ) ヴィクトリーガンダム(再合体):
*分離 ボトムファイター(Ｖ) ヴィクトリーガンダム(再合体):
*分離 トップファイター(ヘキサ) ヴィクトリーガンダムヘキサ:
*分離 ボトムファイター(ヘキサ) ヴィクトリーガンダムヘキサ:
*分離 トップファイター(ヘキサ) ヴィクトリーガンダムヘキサ(再合体):
*分離 ボトムファイター(ヘキサ) ヴィクトリーガンダムヘキサ(再合体):
*分離 トップファイター(Ｖ２) Ｖ２ガンダム:
*分離 ボトムファイター(Ｖ２) Ｖ２ガンダム:
*分離 トップファイター(Ｖ２) Ｖ２ガンダム(再合体):
*分離 ボトムファイター(Ｖ２) Ｖ２ガンダム(再合体):
RecoverHP 対象パイロット 100
Exit
[No.4330] 2015/07/19(Sun) 22:48:19 |
└ 