117180
UWSC 仮 掲示板
投稿時に「証明書が不正です」と出る場合には、JavaScriptをオン
動作不具合での質問の場合には環境を表記(OS,バージョン等)
タイトルは内容を表し、内容はネットゲーム関係禁止
自身でコードを書く気の無いナマケモノは特に質問禁止
失敗作でもコードを投稿すること（具体性の無い質問は無視される可能性大）

UWSC掲示板 が復活することを祈り、それまでの繋ぎとして。
環境設定[s7777777]

Name
Subject
Color
Cookie / Pass
★ Windowsのメディアプレーヤーでストリーミングを視聴 (参考) NEW / ahqiao
素晴らしいUWSCなのに、投稿が少なく寂しい限りです。表題の件、下記します。
1)変数(File)には、ストリーミングのプレイリストを作っておく。
2)メディアプレーヤーの位置とサイズ(X,Y,W,H)は適当に。(下記はPinP風にしてみた)
3)メディアプレーヤーの実行ファイル(RN_WM)の「ZuneVideo」は「ZuneMusic」に置換えてもよい。
気のせいかも知れないが、その他の無料アプリより安定するような気がする。
最近、投稿が少なくなったので、Windowsのメディアプレーヤーの活用事例で、話題になっている
ストリーミングの一つの視聴方法を載せてみた。興味ある方に参考になれば幸いです。
尚、確認したところのOSはWindows10です。
//ここから -------------------------------------------------
OPTION EXPLICIT
DIM File="ストリーミングのプレイリストファイルのフルバス"
DIM Wid, X=(-6), Y=688, W=592, H=(W/16)*9, t=(0.2); W=W+7
DIM Cmd="start"+sc+dq+RN_WM+dq+sc+dq+File+dq; DOSCMD(Cmd)
REPEAT; Sleep(t); Wid=GETID(TL_WM,CL_WM); UNTIL Wid>0
SetWindowPos(IDTOHND(Wid),HWND_TOP,X,Y,W,H,SWP_SHW)
ExitExit
DEF_DLL SetWindowPos(hwnd,hwnd,int,int,int,int,uint):bool:user32.dll
Const RN_WM="shell:AppsFolder\Microsoft.ZuneVideo_8wekyb3d8bbwe!Microsoft.ZuneVideo"
Const CL_WM="ApplicationFrameWindow" ; Const TL_WM="メディア プレーヤー"
Const HWND_TOP=0 ; Const SWP_SHW=$40 ; Const sc=CHR(32) ; Const dq=CHR(34)
//ここまで -------------------------------------------------
No.1763 2025/07/02(Wed) 11:26:51
★ 認識する画像が一つもないときの動作について / yoshiki
下記のようなESCキーを押すまで画像認識し続けるマクロを使用しているのですが、認識する画像が一つもないときの動作を追加しようと考えています。

画像は同時に複数出現することはなく、画像が無いときの動作は画像があるときには起きて欲しくないです。

始めは"While !(CHKIMG(画像A))"の形を取ろうと思ったのですが、画像が増えていくにつれてwhile文も増えていくのが気になりました。

もっと簡潔な記述は無いでしょうか。


-------------
while !(GETKEYSTATE(VK_ESC))

動作A(画像A)
動作B(画像B)
…

動作Z(画像Z)

wend

PROCEDURE 動作A
PROCEDURE 動作B
…

PROCEDURE 動作Z
No.1760 2025/05/30(Fri) 20:08:56
☆ Re: 認識する画像が一つもないときの動作について / stuncloud
> 画像は同時に複数出現することはなく

であればselect文で良いかもしれませんね

select TRUE
　case chkimg(画像A)
　　動作A()
　case chkimg(画像B)
　　動作B()
　case chkimg(画像C)
　　動作C()
　default
　　未発見時動作()
selend

これにより画像が見つかればその時点の動作関数を、いずれの画像もなかった場合は画像なし時の動作をするようになります
例として画像Bが存在する場合は

1. 画像Aを探すが見つからない
2. 画像Bを探し、発見したため動作Bを行う
3. selendへ (Cの探索と画像なし動作は行われない)

という動作になります
画像と対応する動作関数が増えた場合はcase節を追加します
case節は上から順に処理されるため、出現頻度の高い画像ほど上のcaseで探すようにすると効率的です

あとはこれをwhileなどでループさせれば良いでしょう
No.1761 2025/06/01(Sun) 17:45:48
☆ Re: 認識する画像が一つもないときの動作について / ライフス
自分も考えてみました。ESCの処理については省略します。
画像の個数分chkimgを実行するのは変えれません。1つのchkimgでは1つの画像しかチェックできないからです。
procedure 動作A 〜 procedure 動作Zの部分は変えれません。別の処理をするためには別の記述が必要だからです。
どうするか、ループ化するくらいしかなさそうです。
具体的には、すべてのチェック用画像を連番で用意しておきます。数字のほうが簡単ですがアルファベットでもいけます。
　for i=asc("A") to asc("Z")
　　if chkimg("画像" + chr(i))
　　　(処理)
　　　break
　　endif
　next
これで複数の画像をチェックできます。アルファベットの場合26種類を超えるときは少し配慮が必要になります。
連番にできない場合は配列にいれるといいでしょう。
　dim imgnames[] = "画像hoge" , "画像huga" , "画像piyo" , ...
　for i = 0 to length(imgnames)-1
　　if chkimg(imgnames[i])
　　　(処理)
　　　break
　　endif
　next
そして次に、(処理)の部分をどう分けるかですが、基本的にはstuncloudさんと同じように場合分けするしかありません。ではなぜループにしたかというと、evalを使おうと目論んでいるからです。
　for i=1 to 26
　　if chkimg("画像" + i)
　　　eval("動作" + i + "()")
　　　break
　　endif
　next
　if i = 26+1 then 動作x() // breakが動作せず = 画像が一つもマッチしなかった

　procedure 動作1
　　(処理)
　fend
　procedure 動作2
　　(処理)
　fend
...
　procedure 動作x
　　(処理)
　fend
これで、ループでchkimgと動作分けが可能になりました。
行数は多少短くなりましたが、プログラム的に簡潔かといえば胸を張ってはいえないです。evalの使用自体望ましいとはいえません。誤動作しないよう細心の注意が必要になります。しかしこのような書き方はデータ数に対してスケーラブルになる可能性もあるともいえます。
自分はこういったことはまあやります()自分用にしか書かないので
No.1762 2025/06/03(Tue) 01:55:49
★ コンソールアプリの出力結果をタイムリーに受け取りたい / YMK
コンソールアプリが継続的に結果を出力するんだけど、
タイムリーで受け取る方法はありますか？
因みに、Doscmd("コンソールアプリ.exe")
だとアプリが終了するまで出力が受け取れず、

また、Doscmd("コンソールアプリ.exe",True)
だと一切出力が受け取れず、先にuwsが終了してしまいます。。
No.1755 2025/05/07(Wed) 17:33:05
☆ Re: コンソールアプリの出力結果をタイムリーに受け取りたい / レフト
アプリケーションも不明なので試していないですが

print Doscmd("コンソールアプリ.exe")にして
UWSC.LOGに出力してthreadか何かで差分を取得するとかどうですか？
No.1756 2025/05/08(Thu) 14:50:27
☆ Re: コンソールアプリの出力結果をタイムリーに受け取りたい / YMK
動画をダウンロードするアプリで、その進捗を見たいと思っていたのですが、
どうやらこのアプリに限らずコンソールソフト全般は、
終了時にのみ結果を受け取れると言うことが分かったので、
諦めました
No.1757 2025/05/09(Fri) 23:18:21
☆ Re: コンソールアプリの出力結果をタイムリーに受け取りたい / しろまさ
ipconfig>a.txt

出力をテキストアウトしてUWS側で定期的に分析することは可能です
No.1758 2025/05/11(Sun) 15:03:51
☆ Re: コンソールアプリの出力結果をタイムリーに受け取りたい / YMK
>しろまささん
作業の進捗を確認することができました。
有り難うございます。
No.1759 2025/05/11(Sun) 17:15:18
★ pnputil / akira
windows11　ﾊﾞｰｼﾞｮﾝ:24H2
str=doscmd("pnputil /?")
print str
で、strを見ると、
「'pnputil' は、内部コマンドまたは外部コマンド、操作可能なプログラムまたはバッチ ファイルとして認識されていません。」
pnputilは、doscmdでは、使えませんか？

追記
str=doscmd("C:\Windows\sysnative\pnputil.exe /?")
で、使えました。
No.1754 2025/04/20(Sun) 17:46:24
★ CSVにFPUTで計算式を埋め込みたいのですが、カンマで隣のセルに分かれてしまいます。 / sen
お世話になっております。
CSVにFPUTで計算式を埋め込みたいのですが、カンマで隣のセルに分かれてしまいます。
どうすれば良いでしょうか？
ご教授ください。

下記のようなカンマなしの計算式だとうまくいきます。
fput(オ,"=SUM(CV"+i+":CY"+i+")",i,202)



--------------
dim オリジナル梱包f = "オリジナル梱包展開_アイボリーホワイト.csv"

新_P展開数を転記(オリジナル梱包f)

PROCEDURE 新_P展開数を転記(オリジナル梱包f)
オ = fopen(オリジナル梱包f,F_READ or F_WRITE)
for i = 2 to 100
if fget(オ,i,1) = "" then break
DIM テキスト = "=IF($B"+i+"<><#DBL><#DBL>,VLOOKUP($CV$"+i+",$GP:$GQ,2,FALSE)*$B"+i+",<#DBL><#DBL>)"
fput(オ,テキスト,i,100)
next
fclose(オ)
fend
No.1750 2025/03/15(Sat) 23:48:03
☆ Re: CSVにFPUTで計算式を埋め込みたいのですが、カンマで隣のセルに分かれてしまいます。 / sen
お世話になっております。

>0はできました。

DIM テキスト = "<#DBL>=IF($B"+i+">0,VLOOKUP(CV$1,$GP:$GQ,2,FALSE)*$B"+i+",0)<#DBL>"

空白にしようとすると、うまくいきません。
ご教授いただけましたら、ありがたいです。

×　DIM テキスト = "<#DBL>=IF($B"+i+"<><#DBL><#DBL>,VLOOKUP(CV$1,$GP:$GQ,2,FALSE)*$B"+i+",<#DBL><#DBL>)<#DBL>"
No.1751 2025/03/16(Sun) 01:02:35
☆ Re: CSVにFPUTで計算式を埋め込みたいのですが、カンマで隣のセルに分かれてしまいます。 / レフト
そもそもcsvファイルにexcelで開く事を前提にexcel用の数式を記載する時点で誤っていると思います。

・どうしてもならcsvじゃなくてtsvにする（タブ区切り）
・素直にexcelのCOMオブジェクトを使ってxlsxで利用する。
　→数式は.formulaにする
No.1752 2025/03/17(Mon) 11:34:20
☆ Re: CSVにFPUTで計算式を埋め込みたいのですが、カンマで隣のセルに分かれてしまいます。 / sen
回答ありがとうございます。

済みません。
EXCELかWINDOWSがバージョンアップした時に、XLOPENでxlsxが開けなくなりましたが、何故かCSVなら開けます。
そこで、fputでCSVにデータを転記してXLOPENでCSVを開く事をよくしています。
ただ、エクセルで開いた後、数字を変えたいなと思う事もでてきまして、このような質問になりました。

お騒がせしました。
質問の件は試行錯誤の上、INDIRECTとADDRESSを使用してなんとかうまくいきました。
私にはCOMは少し難しいので、今後もfputとCSVとXLOPENで活用していきたいと思います。
UWSCは仕事にしか使用していませんが、今はなくてはならないものとなっております。
計算式を埋め込むという荒技ですが、これで益々UWSCの活用の場が広がり大満足です。

ありがとうございました。


----------------------
DIM テキスト = "<#DBL>=IF(INDIRECT(ADDRESS("+i+","+S+"))>0,VLOOKUP(INDIRECT(ADDRESS(1,"+(100+S-2)+")),$GP:$GQ,2,FALSE)*INDIRECT(ADDRESS("+i+","+S+")),0)<#DBL>"
No.1753 2025/03/18(Tue) 22:56:06
★ キーボード入力中(日本語変換中)の取得方法について / みつ
お世話になります。
今年もよろしくお願いします。

キーボードが入力中(日本語変換中)かどうかを取得したいのですが、以下で上手くいきませんので修正方法または他の方法があれば教えて頂きたいです。


DEF_DLL ImmGetContext(long hwnd): long: IMM32.dll // IMEコンテキストを取得
DEF_DLL ImmGetConversionStatus(long hImc, long &dwConversion, long &dwSentence): bool: IMM32.dll // 変換状態を取得
DEF_DLL ImmReleaseContext(long hwnd, long hImc): bool: IMM32.dll // IMEコンテキストを解放
DEF_DLL GetForegroundWindow(): long: user32.DLL // アクティブウィンドウのハンドルを取得


IFB IsIMEConverting(GetForegroundWindow())
PRINT "現在、日本語変換中です。"
ELSE
PRINT "日本語変換は行われていません。"
ENDIF



FUNCTION IsIMEConverting(hwnd)
DIM hIMC, dwConversion, dwSentence
hIMC = ImmGetContext(hwnd) // 現在のウィンドウのIMEコンテキストを取得
IFB hIMC = 0
RESULT = FALSE // IMEコンテキストの取得に失敗した場合
ENDIF

// 変換状態を取得
result = ImmGetConversionStatus(hIMC, dwConversion, dwSentence)

// 変換状態のビットを確認して、変換中か確定中かを判定
// dwConversion のビットが0x0001の場合、「変換中」または「変換確定中」
IFB (dwConversion AND $0001) = $0001 // 変換中
RESULT = TRUE
ELSE
RESULT = FALSE
ENDIF

// コンテキストの解放
ImmReleaseContext(hwnd, hIMC)
FEND
No.1744 2025/01/05(Sun) 21:03:17
☆ Re: キーボード入力中(日本語変換中)の取得方法について / stuncloud
> 以下で上手くいきませんので
なにがどのようにうまくいかないか、まで書くようにしましょう

いかにもダメそうなのはdef_dllの記述ですね
> DEF_DLL ImmGetContext(long hwnd): long: IMM32.dll // IMEコンテキストを取得
の
> long hwnd
のような書き方は許可されていません
DEF_DLL ImmGetContext(long): long: IMM32.dll
こう書きます
また、ImmGetConversionStatusはDWORDのポインタを受けるので
DEF_DLL ImmGetConversionStatus(long, var dword, var dword): bool: IMM32.dll
となります

ところでImmGetConversionStatusで本当に変換中かどうかを得られるのでしょうか？
> // dwConversion のビットが0x0001の場合、「変換中」または「変換確定中」
これはどのような根拠があるのでしょうか？
ImmGetConversionStatusを調べるとどう見ても変換モードの状態を取得する関数であり、変換中かどうかを調べる用途はなさそうです

そもそもなんですが、imm32はUIスレッドで使う想定のような感じで外部(UWSC)から使うのは不適切なのでは？という気がします
ので結論はちょっとこれは無理じゃね？となります

代替案は正直わかりません
No.1745 2025/01/21(Tue) 00:09:56
☆ Re: キーボード入力中(日本語変換中)の取得方法について / みつ
stuncloudｄさんDEF_DLLの使い方をご教授頂きありがとうございました。

IMEで変換中を捉えたかったのですが、ImmGetConversionStatusでは駄目なのですね。
win32.dllで調べても分からなかったので ChatGPTに聞いた答えが
「dwConversion のビットが0x0001の場合、「変換中」または「変換確定中」」でした。

諦めきれないのでwin32で変換中か判断できないか引き続き調べたいのですが、
DEF_DLLの使い方を説明しているHP等ご存じでしたらご教授頂けないでしょうか。
よろしくお願いいたします。
No.1746 2025/01/25(Sat) 17:54:13
☆ Re: キーボード入力中(日本語変換中)の取得方法について / stuncloud
やはり他のプロセスのウィンドウに対してのImmGetContextが無効であるため、imm32を使った方法は無理でしょう
(これはおそらくセキュリティ上の制限であり、むりやり突破すべきものでもない)

def_dll ImmGetContext(hwnd):dword:imm32.dll
def_dll ImmGetDefaultIMEWnd(hwnd):hwnd:imm32.dll

sckey(0, VK_WIN, VK_R)
id = getid("ファイル名を指定して実行")
hwnd = idtohnd(id)
hime = ImmGetDefaultIMEWnd(hwnd)
print hime // IMEウィンドウのhwndは取れる
himc = ImmGetContext(hime)
print himc // 0 失敗！

IMEの状態取得であればSendMessage + WM_IME_CONTROLで可能です
これは外部からImmGetConversionStatusとほぼ同じことができるということですが、あくまで入力モード等の情報が得られるだけであり入力中かどうかを判断できるものではありません


> DEF_DLLの使い方を説明しているHP等

しゅんさんのところが一番詳しいんですが、少しむずかしいか？
https://junjun777.hatenablog.com/entry/2020/06/11/130010
No.1747 2025/01/28(Tue) 14:28:38
☆ Re: キーボード入力中(日本語変換中)の取得方法について / stuncloud
def_dllを使わずとも、UWSCらしい方法で一応解決できました (欠点あり)

変換中であることを確認するには

・変換中ウィンドウ (Composition window) が表示されている (入力中の点線が引かれている文字列部分)
・変換候補ウィンドウ (Candidate window) が表示されている (変換候補メニュー)
・かつそれらの状態をstatus等で変換中とそれ以外の状態が得られる

が満たせれば良いということになります
これらは変換中の状態でgetid(GET_FROMPOINT_OBJ)を使いidを得ることでstatus等で調べることができます

その結果
・MS IMEであればクラス名が「MSCTFIME Composition」のウィンドウ (変換中ウィンドウ) がST_VISIBLEであれば変換中である
・Google IMEであればクラス名が「GoogleJapaneseInputCandidateWindow」のウィンドウ (変換候補ウィンドウ) がST_VISIBLEであれば変換中である
と言えることがわかりました

ATOKなど他のIMEに関しても同じように調査することで変換状態の取得が可能になるかと思います

欠点はIME毎に判定関数を書く必要があり汎用性に欠けるということですね

以下は実際に試せるコードです
Windows 10で動作を確認しました

sckey(0, VK_WIN, VK_R)
id = getid("ファイル名を指定して実行")
x = status(id, ST_X)
y = status(id, ST_Y)
while status(id, ST_VISIBLE)
　if GoogleIME変換中() then
　　balloon("Google IME 変換中", x, y)
　　while GoogleIME変換中()
　　　sleep(0.1)
　　wend
　　balloon()
　elseif MsIME変換中() then
　　balloon("MS IME 変換中", x, y)
　　while MsIME変換中()
　　　sleep(0.1)
　　wend
　　balloon()
　else
　　sleep(0.1)
　endif
wend

function MsIME変換中()
　result = status(getid("", "MSCTFIME Composition", 0.1), ST_VISIBLE)
fend
function GoogleIME変換中()
　result = status(getid("", "GoogleJapaneseInputCandidateWindow", 0.1), ST_VISIBLE)
fend
No.1748 2025/01/28(Tue) 15:37:15
☆ Re: キーボード入力中(日本語変換中)の取得方法について / みつ
stuncloudｄさん

毎回ドンピシャのご回答および丁寧な説明をして頂きありがとうございます。
今の自分では絶対に辿り着けないコードでした。

また、DEF_DLL の HP も教えて頂きありがとうございます。
いつか理解できるよう頑張りたいと思います。

教えて頂いたコードですが MsIME変換中()とGoogleIME変換中()を試したところ、Ggoole 日本語入力ではGoogleIME変換中()が、全ての箇所でばっちり動いたのですが、
Microsoft IMEでは、MsIME変換中()がメモ帳以外の Edge や Chorme 上では認識されませんでした。

色々とクラスを変更して試してみたのですが上手く認識されませんので、もし設定等があればご教授頂けないでしょうか。
PC は Windows 10 です

よろしくお願いいたします。
No.1749 2025/01/29(Wed) 23:00:54
★ 改行コード / seed
お世話になります。
改行コードの<#CR>をテキストやフォームに表示させるスクリプトを組むと改行されてしまいます。
<#DBL>やダブルコーテイションで囲っても改行されてしまいます。
改行されずに、以下の文を表示させる方法はないのでしょうか。

※改行したくない<#CR>改行したくない
改行したくない
No.1741 2024/11/07(Thu) 06:53:04
☆ Re: 改行コード / ねこ
こういうことでしょうか？

print "※改行したくない<" + "#CR>改行したくない" + "<#CR>" +"改行したくない"
No.1742 2024/11/15(Fri) 14:33:46
☆ Re: 改行コード / seed
ありがとうございます、解決しました。
No.1743 2024/11/17(Sun) 18:30:12
★ SENDSTRの改行 / ROM
お世話になります。
SENDSTRを用いてメモ帳にメッセージを表示しています。
Win10では<#CR>で改行していましたが、Win11では改行できなくなりました。
ご教示いただければ、幸いです。よろしくお願いします。

プログラム：
　FID=EXDEC("noepad.exe")
　SENDSTR(FID,"ABC<#CR>DEF")

⇒Win10の場合
ABC
DEF
と表示される。
⇒Win11の場合
ABCDEF
と表示される。
No.1739 2024/08/07(Wed) 21:38:18
☆ Re: SENDSTRの改行 / stuncloud
興味深いので調べてみました

解決策は案外簡単で
sendstr(id,"ABC<#CR>DEF", 1)
のように送信するコントロールを1番目と明示するだけでした

Windows 11のメモ帳は入力部分がリッチエディットコントロールになっていて、デフォルト (0) でフォーカスされたコントロールに対しての送信だと改行の扱いが変わるのかもしれませんね
No.1740 2024/08/19(Mon) 13:09:10
★ MOUSEORG関数について / ben
質問失礼します。

mouseorg(id, morg_direct)
sleep(2)
print "a"
btn(left,click,x,y)

上のようにmouseorg関数の引数にmorg_directを指定しているとき、
CTRLキーを押したままにしていると３行目までは動作しますが４行目のクリックがCTRLキーを離すまで動作しません。

この問題は自分の環境だけで起こっているのでしょうか？

CTRLキーを押したままでも動作する方法がありましたら教えていただきたいです。

環境
・windows10
・UWSC ver 5.3.0.2
No.1738 2024/08/04(Sun) 18:47:10
★ Error: 最大FILE_OEPN数=64 を超えました / sen
いつもお世話になっております。
以前教えて頂いたfindstrを使って転記していたのですが、今回だけうまくいきません。
以前のを修正しただけなのでうまくいくはずなのですが、ファイルオープン数のエラーが発生します。
ご教授ください。


「Error: 最大FILE_OEPN数=64 を超えました 10行目: 抽出 = FOPEN("temp.csv",F_WRITE)」

データは下記のようなほぼ同一のデータで、取寄日が空白の場合は「入荷日調査.CSV」から
取寄日を転記します。


前の残_糸川.CSV
得意先名,直送先名,受注番号,担当者名,業者名,品名,組立業者名,納品日,必要日,納期,取寄日,品番,数量
松戸店,松戸店,04/02-570-01-01,高田,白方,ﾊｺ,吉田,2024/08/31,2024/08/30,24/08/31,2024/05/06,A-2014,1
松戸店,松戸店,04/02-571-01-01,高田,白方,ﾊｺ,吉田,2024/08/31,2024/08/30,24/08/31,,A-2014,1
松戸店,松戸店,04/02-572-01-01,高田,白方,ﾊｺ,吉田,2024/08/31,2024/08/30,24/08/31,2024/05/06,A-2014,1

入荷日調査.CSV
得意先名,直送先名,受注番号,担当者名,業者名,品名,組立業者名,納品日,必要日,納期,取寄日,品番,数量
松戸店,松戸店,04/02-571-01-01,高田,白方,ﾊｺ,吉田,2024/08/31,2024/08/30,24/08/31,2024/08/30,A-2014,1


dim 前の残="前の残_糸川.CSV"
dim 入荷日調査="入荷日調査.csv"

P手動で追加した取寄日を受注残に追加findstr(入荷日調査,前の残)

PROCEDURE P手動で追加した取寄日を受注残に追加findstr(入荷日調査,前の残)
dim 前の残??,入荷日調査??,取寄日
残 = fopen(前の残,F_READ or F_WRITE)
For z = 1 to fget(残,-1)
抽出 = fopen("temp.csv",f_write)
if fget(残,z,1) = "" then break
if fget(残,z,11) <> "" then continue
前の残?? = fget(残,z,3)
print 前の残??
該当する行 = doscmd("findstr " + 前の残?? +" "+ 入荷日調査)
if 該当する行 <> "" then fput(抽出,該当する行)
fclose(抽出)
抽出 = FOPEN("temp.csv")
For i = 1 to FGET(抽出, -1)
入荷日調査?? = fget(抽出,i,3)
ifb 入荷日調査?? = 前の残?? then
取寄日 = fget(抽出,i,11)
fput(残,取寄日,z,11)
break
endif
next
FCLOSE(抽出)
next
fclose(残)
FEND
No.1735 2024/07/07(Sun) 09:37:18
☆ Re: Error: 最大FILE_OEPN数=64 を超えました / しろまさ
break直前にfclose(抽出)するだけ。
No.1736 2024/07/08(Mon) 08:19:57
☆ Re: Error: 最大FILE_OEPN数=64 を超えました / sen
そうなんですか。
やってみます。

ありがとうございました。
No.1737 2024/07/08(Mon) 23:03:26

以下のフォームに記事No.と投稿時のパスワードを入力すれば
投稿後に記事の編集や削除が行えます。
200/200件 [ ページ : 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 ... 20 >> ]
- HOME - お知らせ(3/8) - 記事検索 - 携帯用URL - フィード - ヘルプ - メール - 環境設定 -
- Skin: Modern v2.0 - Author: ロケットBBS -
Rocket Board Type-X (Free) Rocket BBS